影羽連盟

on run
    activate
    
    set movieItem to choose file with prompt "ムービーファイルを選択してください" default location (path to home folder) without invisibles
    set textItem to choose file with prompt "チャプターファイルを選択してください" default location (path to home folder) without invisibles
    set saveFolder to choose folder with prompt "保存先フォルダを指定してください" default location (path to movies folder) without invisibles
    
    tell application "QuickTime Player"
        launch
        activate
        stop every document
        close every document saving no
        
        open the movieItem
        tell document 1
            set the trackList to the name of every track
            set the ownerTrack to choose from list trackList with prompt "チャプタを設定するトラックを指定してください"
            set the ownerTrack to the ownerTrack as string
        end tell
        
        set the openStatus to open movie in new player
        set open movie in new player to true
        open the textItem
        set open movie in new player to the openStatus
        tell document 1
            set the name of track 1 to "Chapter Track"
            rewind
            select all
            copy
            select none
        end tell
        close document 1 saving no
        
        tell document 1
            select none
            rewind
            select all
            add with scaled
            select none
            rewind
            select at 0 to 0
            set preload of track "Chapter Track" to true
            set enabled of track "Chapter Track" to false
            set chapterlist of track ownerTrack to track "Chapter Track"
            set language of track "Chapter Track" to "Japanese"
            
            set enabled of track "Chapter Track" to true
            set enabled of track "Chapter Track" to false
        end tell
        
        set file_name to name of document 1
        set new_file to ((saveFolder as text) & file_name) as string
        save self contained document 1 in new_file
        close document 1 saving no
        quit
    end tell
end run